plugin-meta/build.gradle.kts at master · SpongePowered/plugin-meta · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
plugins {
    id("org.spongepowered.gradle.sponge.dev") version "2.1.1"
    id("org.spongepowered.gradle.repository") version "2.1.1"
    id("net.kyori.indra.checkstyle") version "3.2.0"
    id("net.kyori.indra.crossdoc") version "3.2.0"
    id("net.kyori.indra.publishing.sonatype") version "3.2.0"
}

repositories {
    sponge.all()
}

dependencies {
    compileOnlyApi("org.checkerframework:checker-qual:3.42.0")
    api("com.google.code.gson:gson:2.10.1")
    api("org.apache.maven:maven-artifact:3.9.16")
    testImplementation("org.junit.jupiter:junit-jupiter-api:5.10.2")
    testRuntimeOnly("org.junit.jupiter:junit-jupiter-engine:5.10.2")
}

spongeConvention {
    repository("plugin-meta") {
        ci(true)
        publishing(true)
    }
    mitLicense()
    licenseParameters {
        this["organization"] = rootProject.property("organization")
    }
}

indra {
    javaVersions().target(21)
}

indraCrossdoc {
    baseUrl(providers.gradleProperty("javadocPublishRoot"))
}

tasks {
    withType(JavaCompile::class).configureEach {
        doFirst {
            options.compilerArgs.addAll(listOf("--module-path", classpath.asPath, "--module-version", project.version.toString()))
        }
    }
    javadoc {
        (options as StandardJavadocDocletOptions).links(
            "https://www.javadoc.io/doc/com.google.code.gson/gson/2.10.1/",
            "https://checkerframework.org/api/",
            "https://maven.apache.org/ref/3.9.16/maven-artifact/apidocs"
        )

        doFirst {
            options.modulePath(classpath.toList())
        }
    }
}