PKGBUILD

# Maintainer: Bruno Goncalves <bigbruno@gmail.com>
# shellcheck shell=bash disable=SC2034,SC2154

pkgname=bigocrpdf
pkgdesc="The simplest way to apply OCR to your PDF files, making it possible to search and copy texts from scanned files."

depends=(
	'gtk4>=4.14'
	'libadwaita>=1.5'
	'hicolor-icon-theme'
	'python>=3.12'
	'python-gobject'
	'python-cairo'
	# RapidOCR core
	'python-rapidocr'
	'rapidocr-fonts'
	# Unified PP-OCRv6 model (Chinese, English, Japanese and Latin scripts)
	'rapidocr-models-v6-small'
	# OCR inference backend
	'python-openvino'
	# PDF processing
	'python-pikepdf'
	'python-pillow'
	'python-reportlab'
	'poppler'
	# Image processing
	'python-opencv'
	'python-numpy'
	# Dewarp dependencies (for curved page correction)
	'python-scipy'
	# ODF export
	'python-odfpy'
)

makedepends=(
	'gettext'
	'git'
	'python-build'
	'python-installer'
	'python-setuptools'
	'python-wheel'
)

# Rolling package: the build fires on every push and the version is the build
# date, which is also where the published artifact tags get their name
# (bigocrpdf-26.06.18-0243-x86_64). Pinning a tag here instead broke the build
# on a tag that was never created, and would have been wrong even if it had
# been: .github/workflows/build-package.yml passes the pushed *branch* to the
# builder, so a tag in the source line would build the same commit whatever
# branch was pushed.
pkgver=$(date +%y.%m.%d)
pkgrel=$(date +%H%M)
arch=('any')
license=('GPL-3.0-or-later')
url="https://github.com/biglinux/bigocrpdf"
options=('!strip')

source=("${pkgname}::git+${url}.git")
sha256sums=('SKIP')

optdepends=(
	# Resource detection
	'python-psutil: accurate available-memory detection'
	# Screenshot capture
	'spectacle: screenshot capture on KDE Plasma'
	'gnome-screenshot: screenshot capture on GNOME'
	'flameshot: cross-desktop screenshot capture'
	# File manager integration
	'python-nautilus: GNOME Files (Nautilus) context menu integration'
	'nemo-python: Nemo file manager context menu integration'
	# Alternative inference backend
	'python-onnxruntime: Alternative inference backend (fallback)'
	# PDF/A ICC profile fallback
	'ghostscript: sRGB ICC profile for PDF/A-2b conversion'
	# Optional best compression for bilevel PDF output
	'jbig2enc: smaller Black & White PDF output; CCITT G4 is used when absent'
)

build() {
	cd "${srcdir}/${pkgname}" || return 1
	rm -rf "${srcdir}/dist"
	python -m build --wheel --no-isolation --skip-dependency-check --outdir "${srcdir}/dist"
}

package() {
	cd "${srcdir}/${pkgname}" || return 1

	# Install Python wheel
	python -m installer --destdir="$pkgdir" "${srcdir}"/dist/*.whl

	# Install metadata and compile gettext catalogs without modifying the source tree.
	bash tools/stage-data.sh "$pkgdir"
}