starbind/flake.nix at master · corpix/starbind · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
{
  inputs = {
    nixpkgs.url = "tarball+https://git.tatikoma.dev/corpix/nixpkgs/archive/corpix.tar.gz";
    flake-utils.url = "github:numtide/flake-utils";

    treefmt-nix.url = "github:numtide/treefmt-nix";
    treefmt-nix.inputs.nixpkgs.follows = "nixpkgs";
  };

  outputs =
    {
      self,
      nixpkgs,
      flake-utils,
      treefmt-nix,
      ...
    }:
    let
      inherit (flake-utils.lib)
        eachSystem
        allSystems
        ;

      mkSystems = eachSystem allSystems;
      mkArch =
        arch:
        let
          pkgs = import nixpkgs {
            system = arch;
            config = {
              allowUnfree = true;
            };
          };

          treefmtEval = treefmt-nix.lib.evalModule pkgs ./nix/treefmt.nix;
        in
        {
          packages = {
            starbind = pkgs.buildGoModule {
              pname = "starbind";
              version = "0-unstable";

              src = self;
              vendorHash = null;
              ldflags = [
                "-s"
                "-w"
              ];
              subPackages = [ "cmd/starbind" ];

              meta = {
                mainProgram = "starbind";
                description = "Generate Starlark bindings for Go code";
              };
            };
            default = self.packages.${arch}.starbind;
          };

          formatter = treefmtEval.config.build.wrapper;

          checks = {
            formatting = treefmtEval.config.build.check self;
            inherit (self.packages.${arch}) starbind;
          };

          devShells.default = pkgs.mkShell {
            name = "starbind";
            packages =
              (with pkgs; [
                coreutils
                findutils
                git
                gnumake
                just
                tree

                go
                gopls
                delve
                golangci-lint
                gofumpt
                gotools
              ])
              ++ [
                treefmtEval.config.build.wrapper
              ];
            shellHook = ''
              export GOTELEMETRY=off
              export NIX_PATH=nixpkgs=${nixpkgs}
            '';
          };
        };
    in
    mkSystems mkArch;
}