Port low stratiform cloud fraction optics limiter from CAM micro_pumas_cam

Author: Haipeng Lin

schemes/pumas/micro_pumas_ccpp_optics_limiter.F90

@@ -0,0 +1,60 @@
+module micro_pumas_ccpp_optics_limiter
+
+  use ccpp_kinds, only: kind_phys
+
+  implicit none
+  private
+
+  public :: micro_pumas_ccpp_optics_limiter_run
+
+  !Convective size distribution parameters, used in place of the stratiform
+  !parameters where the stratiform cloud fraction is negligible.
+  !Mirrors CAM micro_pumas_cam.F90.
+  real(kind_phys), parameter :: dcon   = 25.e-6_kind_phys !Convective size distribution effective radius (m)
+  real(kind_phys), parameter :: mucon  = 5.3_kind_phys    !Convective size distribution shape parameter (1)
+  real(kind_phys), parameter :: deicon = 50._kind_phys    !Convective ice effective diameter (um)
+
+  !Stratiform cloud fraction below which the stratiform size distribution is
+  !discarded. PUMAS divides cloud water by the cloud fraction to obtain the
+  !in-cloud values these parameters are derived from, so as the cloud fraction
+  !vanishes the slope and diameters it produces grow without bound.
+  real(kind_phys), parameter :: cldfrc_min = 1.e-4_kind_phys
+
+contains
+  !> \section arg_table_micro_pumas_ccpp_optics_limiter_run Argument Table
+  !! \htmlinclude micro_pumas_ccpp_optics_limiter_run.html
+  subroutine micro_pumas_ccpp_optics_limiter_run(ncol, nlev, trop_cloud_top_lev,   &
+                   strat_cldfrc, pgamrad, lamcrad, deffi, errmsg, errcode)
+
+    integer,            intent(in)    :: ncol               !Number of horizontal columns (count)
+    integer,            intent(in)    :: nlev               !Number of vertical layers (count)
+    integer,            intent(in)    :: trop_cloud_top_lev !Index of the top model level for which
+                                                            !tropospheric cloud physics is run (index)
+    real(kind_phys),    intent(in)    :: strat_cldfrc(:, :) !Stratiform cloud area fraction (fraction)
+    real(kind_phys),    intent(inout) :: pgamrad(:, :)      !Size distribution shape parameter (1)
+    real(kind_phys),    intent(inout) :: lamcrad(:, :)      !Slope of droplet distribution (m-1)
+    real(kind_phys),    intent(inout) :: deffi(:, :)        !Effective diameter of cloud ice particle (um)
+    character(len=512), intent(out)   :: errmsg             !CCPP error message (none)
+    integer,            intent(out)   :: errcode            !CCPP error code (1)
+
+    integer :: i, k
+
+    errmsg  = ''
+    errcode = 0
+
+    !lamcrad is an inverse length; it is declared dimensionless in the metadata
+    !to match the RRTMGP and host declarations, so dcon must stay in meters for
+    !the value handed to radiation to be consistent with CAM.
+    do k = trop_cloud_top_lev, nlev
+       do i = 1, ncol
+          if (strat_cldfrc(i, k) < cldfrc_min) then
+             pgamrad(i, k) = mucon
+             lamcrad(i, k) = (mucon + 1._kind_phys) / dcon
+             deffi(i, k)   = deicon
+          end if
+       end do
+    end do
+
+  end subroutine micro_pumas_ccpp_optics_limiter_run
+
+end module micro_pumas_ccpp_optics_limiter

schemes/pumas/micro_pumas_ccpp_optics_limiter.meta

@@ -0,0 +1,77 @@
+[ccpp-table-properties]
+  name = micro_pumas_ccpp_optics_limiter
+  type = scheme
+########################################################################
+[ccpp-arg-table]
+  name = micro_pumas_ccpp_optics_limiter_run
+  type = scheme
+
+##### Run Arguments
+[ncol]
+  standard_name = horizontal_loop_extent
+  long_name = number of horizontal columns
+  units = count
+  dimensions = ()
+  type = integer
+  intent = in
+[nlev]
+  standard_name = vertical_layer_dimension
+  long_name = vertical layer dimension
+  units = count
+  dimensions = ()
+  type = integer
+  intent = in
+[trop_cloud_top_lev]
+  standard_name = vertical_layer_index_of_troposphere_cloud_physics_top
+  long_name = vertical layer index of troposphere cloud physics top
+  units = index
+  dimensions = ()
+  type = integer
+  intent = in
+[strat_cldfrc]
+  standard_name = stratiform_cloud_area_fraction
+  long_name = stratiform cloud area fraction
+  units = fraction
+  dimensions = (horizontal_loop_extent, vertical_layer_dimension)
+  type = real
+  kind = kind_phys
+  intent = in
+[pgamrad]
+  standard_name = size_distribution_shape_parameter_for_microphysics
+  long_name = cloud particle size distribution shape (gamma) parameter
+  units = 1
+  dimensions = (horizontal_loop_extent, vertical_layer_dimension)
+  type = real
+  kind = kind_phys
+  intent = inout
+[lamcrad]
+  standard_name = slope_of_droplet_distribution_for_optics
+  long_name = cloud particle size distribution slope (lambda) parameter
+  units = 1
+  dimensions = (horizontal_loop_extent, vertical_layer_dimension)
+  type = real
+  kind = kind_phys
+  intent = inout
+[deffi]
+  standard_name = effective_diameter_of_stratiform_cloud_ice_particle_for_radiation
+  long_name = effective diameter of stratiform cloud ice particles for radiation
+  units = um
+  dimensions = (horizontal_loop_extent, vertical_layer_dimension)
+  type = real
+  kind = kind_phys
+  intent = inout
+[errmsg]
+  standard_name = ccpp_error_message
+  long_name = error message for error handling in CCPP
+  units = none
+  dimensions = ()
+  type = character
+  kind = len=512
+  intent = out
+[errcode]
+  standard_name = ccpp_error_code
+  long_name = error code for error handling in CCPP
+  units = 1
+  dimensions = ()
+  type = integer
+  intent = out